今天有個(gè)需求要在 Windows 下實(shí)現(xiàn)數(shù)據(jù)庫自動(dòng)備份，拼湊了一下解決辦法。 

實(shí)現(xiàn)的特性 
可指定多個(gè)數(shù)據(jù)庫 
按照 年/月/日 的方式組織備份 
可選的使用 WinRAR 壓縮備份 
使用計(jì)劃任務(wù)實(shí)現(xiàn)定時(shí)備份 

具體代碼 
備份 

復(fù)制代碼代碼如下:

@echo off & setlocal ENABLEEXTENSIONS 

:: ---------- 配置項(xiàng) ---------- 

:: 備份放置的路徑，加 \ 
set BACKUP_PATH=D:\Backup\ 

:: 要備份的數(shù)據(jù)庫名稱，多個(gè)用空格分隔 
set DATABASES=database1 database2 database3 

:: MySQL 用戶名 
set USERNAME=root 

:: MySQL 密碼 
set PASSWORD=123456 

:: MySQL Bin 目錄，加 \ 
:: 如果可以直接使用 mysqldump（安裝時(shí)添加 MySQL Bin 目錄到了環(huán)境變量），此處留空即可 
set MYSQL=D:\SERVER\MySQL\bin\ 

:: WinRAR 自帶命令行工具的可執(zhí)行文件路徑，長文件名注意用 Dos 長文件名書寫方式 
set WINRAR=C:\Progra~1\WinRAR\Rar.exe 

:: ---------- 以下請(qǐng)勿修改 ---------- 

set YEAR=%date:~0,4% 
set MONTH=%date:~5,2% 
set DAY=%date:~8,2% 
:: 如果在 dos 下輸入 time 返回的不是 24 小時(shí)制（沒有 0 填充），請(qǐng)自行修改此處 
set HOUR=%time:~0,2% 
set MINUTE=%time:~3,2% 
set SECOND=%time:~6,2% 

set DIR=%BACKUP_PATH%%YEAR%\%MONTH%\%DAY%\ 
set ADDON=%YEAR%%MONTH%%DAY%%HOUR%%MINUTE%%SECOND% 

:: create dir 
if not exist %DIR% ( 
mkdir %DIR% 2>nul 
) 
if not exist %DIR% ( 
echo Backup path: %DIR% not exists, create dir failed. 
goto exit 
) 
cd /d %DIR% 

:: backup 
echo Start dump databases... 
for %%D in (%DATABASES%) do ( 
echo Dumping database %%D ... 
%MYSQL%mysqldump -u%USERNAME% -p%PASSWORD% %%D > %%D.%ADDON%.sql 2>nul 
:: winrar 
if exist %WINRAR% ( 
%WINRAR% a -k -r -s -m1 -ep1 %%D.%ADDON%.rar %%D.%ADDON%.sql 2>nul 
del /F /S /Q %%D.%ADDON%.sql 2>nul 
) 
) 
echo Done 

:exit 

增加計(jì)劃任務(wù) 

復(fù)制代碼代碼如下:

@echo off 

:: ------- 配置項(xiàng) ------- 

:: 要執(zhí)行的文件名 
set FILE=D:\cron\cron_backup.bat 

:: 計(jì)劃頻率類型 
set FREQUENCY=DAILY 

:: 頻率，與上面的計(jì)劃頻率類型對(duì)應(yīng) 
set MODIFIER=1 

:: 該計(jì)劃執(zhí)行的時(shí)間（24 小時(shí)制） 
set DATETIME=00:30:00 

:: 計(jì)劃的名字 
set NAME="Backup Cron Job" 

:: 計(jì)劃執(zhí)行用戶，不建議修改 
set USER="System" 

:: ------- 以下請(qǐng)勿修改 ------- 

schtasks /Create /RU %USER% /SC %FREQUENCY% /MO %MODIFIER% /ST %DATETIME% /TN %NAME% /TR %FILE% 
pause 

其中的 

:: 計(jì)劃頻率類型，可選項(xiàng)： 
:: MINUTE 分鐘 
:: DAILY 天 
:: HOURLY 小時(shí) 
:: WEEKLY 周 
:: MONTHLY 月 

:: 頻率，與上面的計(jì)劃頻率類型對(duì)應(yīng) 
:: MINUTE: 1 到 1439 分鐘 
:: HOURLY: 1 - 23 小時(shí) 
:: DAILY: 1 到 365 天 
:: WEEKLY: 1 到 52 周 
:: MONTHLY: 1 到 12，或 FIRST, SECOND, THIRD, FOURTH, LAST, LASTDAY 

使用方法 
將上面的兩段代碼分別保存為 cron_backup.bat 和 cron_backup_add.bat，并根據(jù)注釋修改相關(guān)參數(shù) 
確定好目錄之后，運(yùn)行 cron_backup_add.bat 將計(jì)劃任務(wù)添加到系統(tǒng)中。 
Windows Server 2003 / XP 可以通過 開始，控制面板，計(jì)劃任務(wù)進(jìn)入計(jì)劃任務(wù)管理界面； 
Windows Vista / 7 可以通過 計(jì)算機(jī)，右鍵，管理，系統(tǒng)工具，任務(wù)計(jì)劃程序，任務(wù)計(jì)劃程序庫，進(jìn)入計(jì)劃任務(wù)管理界面。 
手動(dòng)運(yùn)行該任務(wù)，查看備份目錄來確認(rèn)下備份是否成功。 

待改進(jìn) 
增加刪除多少天之前備份的功能